D言語からObjective-CとCocoaAPIを使いたい

{
    "authors": ["hidhok"],
    "description": "A D/Objective-C Cocoa application.",
    "name": "flag",
    "dflags": ["-L-framework", "-LCocoa"],
    "sourceFiles": ["../cocoa/window",
                    "../cocoa/control",
                    "../cocoa/menus"]
}               

/**
 *    flag/source/app.d       Version 0.0.5
 */
module flag.main;
import core.attribute : optional, selector;
import std.conv : to;
import std.math;
import std.stdio;
import cocoa.window;
import cocoa.control;
import cocoa.menus;

string appName;
string versionNo = "0.0.5";
string helpMessage =  "CocoaAPIを使用して 日章旗 を、\nD言語で表示してみました。";

void main() {
    auto delegate_ = AppDelegate.alloc.init;
    NSApp.delegate_ = cast(void*) delegate_;
	NSApp.activationPolicy = NSAppActivationPolicy.regular;
    NSApp.run;
}

extern (Objective-C)
class DrawView : NSView {
	override static DrawView alloc() @selector("alloc");
    override DrawView init() @selector("init");
	override DrawView init(NSRect) @selector("initWithFrame:");
	override void drawRect(NSRect r) @selector("drawRect:") {
        NSPoint center;
        CGFloat radius, flagW, flagH;
        NSRect flagRect, dotRect;
        CGFloat w = r.size.width;
        CGFloat h = r.size.height;
        center.x = w / 2;
        center.y = h / 2;

        NSColor.cyan.setFill;
        NSRectFill(r);
        if (w > h * 1.5) {
            flagH = h - 20;
            flagW = flagH * 3 / 2;
        } else {
            flagW = w - 20;
            flagH = flagW * 2 / 3;
        }
        radius = flagH * 0.3;
        flagRect = NSMakeRect(center.x - flagW / 2, 
                              center.y - flagH / 2, flagW, flagH);
        NSColor.white.set;
        NSRectFill(flagRect);
        dotRect = NSMakeRect(center.x - radius, 
                             center.y - radius, radius * 2, radius * 2);
        NSBezierPath path = NSBezierPath.bezierPath;
        NSColor.red.set;
        path = NSBezierPath.ovalInRect(dotRect);
        path.fill;
    } 
}

extern (Objective-C)
class AppDelegate : NSObject {
    override static AppDelegate alloc() @selector("alloc");
    override typeof(this) init() @selector("init");
    bool applicationShouldTerminateAfterLastWindowClosed(
            NSNotification notification) @selector(
            "applicationShouldTerminateAfterLastWindowClosed:") {
        return true;
    }
    void applicationDidFinishLaunching(NSNotification notification) 
                @selector("applicationDidFinishLaunching:") {
        buildWindow;
    }
    void aboutPanel() @selector("aboutPanel") {
        dialog(appName, "Version " ~ versionNo);
    }
    void showHelp() @selector("showHelp") {
        dialog("Help", helpMessage);
    }
} 

void buildWindow() {
    NSWindow win;
    NSRect w_rect = NSMakeRect(100, 550, 400, 400);
    appName = NSProcessInfo.processInfo.processName.toDs;
    NSApp.menu = miniMenu(appName);
    immutable w_style = NSWindowStyleMask.titled |
                        NSWindowStyleMask.closable |
                        NSWindowStyleMask.resizable |
                        NSWindowStyleMask.miniaturizable;
    win = NSWindow.alloc.init(w_rect, w_style, backing.buffered, false);
    win.title = (appName ~ " (D言語テスト)").toNs;
    DrawView dView = DrawView.alloc.init;
    win.contentView = dView;
    // dView.bgColor = NSColor.cyan;
    ViewController vCtrler = ViewController.alloc.init;
    vCtrler.view.subview = dView;
    win.makeKeyAndOrderFront = null;
    NSApp.activateIgnoringOtherApps = true;
}

extern (Objective-C) 
class ViewController : NSViewController {
    override static ViewController alloc() @selector("alloc");
    override ViewController init() @selector("init");
    override void loadView() @selector("loadView") {
        printf("loadView\n");
    }
    override void viewDidLoad() @selector("viewDidLoad") {
        printf("viewDidLoad\n");
    }
}